Hoi Allemaal,

Ik probeer een nieuwe Shortcut te maken waarin ik een in de finder geselecteerde jpg toe wil voegen aan Numbers.

Maar ik krijg het niet voor elkaar. Het enige wat gebeurd is dat de filename van de foto in een colom verschijnt.

Weet iemand hoe ik dit wel voor elkaar krijg?

Als ik bv handmatig een jpg in een cell plak, dan lukt het wel. Maar ik wil dit dus via de Shortcuts automatiseren.

Het is mij niet helemaal duidelijk wat je juist beoogt, ook niet wat de OS versie is, maar op het eerste zicht is er geen directe ondersteuning om de achtergrond van een Numbers cel te vullen met een plaatje (want dat is wat er blijkbaar gebeurt wanneer je een plaatje plakt in een cel).

De Shortcuts taak in bijlage is maar een 'happy day' voorbeeld en bestaat uit drie stappen:
- een start stap voor een Quick Action op bestanden met plaatjes in Finder
- een stap die een Numbers document selecteert en opent
- een AppleScript stap die het eigenlijke werk uitvoert.



De AppleScript stap simuleert de manuele cel selectie en kopieer / plak acties:
- lees het input bestand (met het plaatje) in het klembord
- selecteer de cel in het geopende Numbers document waar de afbeelding moet geplakt worden
- simuleer een manuele plak actie alsof je zelf op de menu's klikt (mogelijk moet je namen als "Paste" vertalen naar het Nederlands).

Om een en ander te kunnen uitvoeren moet je eventueel ook wat permissies geven in de privacy instellingen.

Aanvulling

De volgende versie van het AppleScript vereenvoudigt de plak actie.

on run {input, parameters}
set the clipboard to (read item 1 of input as TIFF picture)

tell application "Numbers"
tell table 1 of sheet 1 of document 1
set selection range to range "B2:B2"
end tell
end tell
tell application "System Events" to keystroke "v" using command down

return input
end run


Danks, ik ga het binnenkort proberen.

Ik krijg dus inderdaad een melding dat Shortcuts is not allowed to send keystrokes.

Ik heb bij de privacy settings full disk access gegeven aan shortcuts, maar dat mag niet helpen, ik krijg dezelfde melding?

Wat moet ik waar instellen om dit werkend te krijgen?

Ik werk trouwens in Monterey.

Wat moet ik waar instellen om dit werkend te krijgen?

Ik heb bij Privacy Settings > Accessibility een aangevinkte siriactionsd 'applicatie' (als dat niet werkt kan je de (langere) eerste versie proberen uit de schermafbeelding). Ook Monterey hier.

Yup! Dat werkt! Super, ik ga er verder mee aan de slag.

Okay (MCMT):

Ik heb het 2e kortere script dat je had aangedragen gebruikt, en het werkt.

Nu de volgende vraag:

Ik zou graag automatisch in de cell naast het image bestand, de filename van dat image bestand willen krijgen.

Hoe zou ik dat met een script kunnen aanroepen?

Je kan het tweede script eventueel als volgt uitbreiden (zet de bestandsnaam in cell "A2"):

on run {input, parameters}
set the clipboard to (read item 1 of input as TIFF picture)
set filename to name of (info for item 1 of input)

tell application "Numbers"
tell table 1 of sheet 1 of document 1
set value of cell "A2" to filename
set selection range to range "B2:B2"
end tell
end tell
tell application "System Events" to keystroke "v" using command down

return input
end run
.

Perfefct!

Dit werkt prima.

Nu alleen nog een repeat functie..

Ik heb een shortcut loop geprobeerd, maar dan krijg ik alleen maar enkele Numbers documenten met 1 foto en filename.

Ik wil graag, als ik 10 images selecteer, dat hij dan 10 rows vult met de 10 images en de filenames.

Hoe kan ik het script dat laten doen?

Je kan het AppleScript in een repeat loop zetten zoals hieronder aangegeven. Voor elke gekozen afbeelding wordt dan het script opgeroepen.



Het script verschilt in grote lijnen van het vorige op volgende punten:
- Het voegt een rij toe onderaan de tabel, en vult daar in kolom A de bestandsnaam in, en in kolom B het eigenlijke plaatje.
- Het script bevat ook een pauze van 1 seconde (delay 1). Heel netjes is het niet, maar dit komt door de manier waarop het plaatje in de cel gestoken wordt m.b.v. het klembord, wat asynchrone verwerking met zich mee brengt. Misschien kan de pauze wat korter, eventueel moet die wat langer.

on run {input, parameters}
set the clipboard to (read input as TIFF picture)
set filename to name of (info for input)

tell application "Numbers"
tell table 1 of sheet 1 of document 1
set i to row count + 1
set row count to i
set value of cell ("A" & i) to filename
set selection range to range ("B" & i)
end tell
end tell
tell application "System Events" to keystroke "v" using command down
delay 1
return input
end run


Als ik met het laatste script 1 afbeelding selecteer, gaat het prima. Maar als ik er twee of meer kies, krijg ik een foutmelding. Ook als ik de het script aanpas naar 3 seconden bv.

Dit is wat ik te zien krijg:

Dat laatste script verwacht opgeroepen te worden vanuit een Repeat with... loop (zie mijn schermafbeelding), met Repeat Item (en niet de Shortcut Input) als input.

Alternatief is de eerdere shortcut te behouden en de loop rechtstreeks in het script zelf te zetten, zoals hieronder.

on run {input, parameters}
repeat with each in input
set the clipboard to (read each as TIFF picture)
set filename to name of (info for each)

tell application "Numbers"
tell table 1 of sheet 1 of document 1
set i to row count + 1
set row count to i
set value of cell ("A" & i) to filename
set selection range to range ("B" & i)
end tell
end tell
tell application "System Events" to keystroke "v" using command down
delay 1
end repeat

return input
end run


Dat laatste script verwacht opgeroepen te worden vanuit een Repeat with... loop (zie mijn schermafbeelding), met Repeat Item (en niet de Shortcut Input) als input.

ahhhh... sorry, ik zie het nu. Ik heb niet goed gekeken, naar de layout boven het script...

Ik zal nog eens wat proberen.

Het werk!

Superbedankt voor je hulp. Ik ben hier erg blij mee.

Adventurous greetings, Coen.